Difference between revisions of "Anri-chan/Source/statid.bat"

Revision as of 22:58, 2 August 2007

@echo off

echo This batch will create a preview version of your Station ID called statid_preview.avi on your desktop.
echo

(SET anri_dir=%~dp0)
XCOPY /Y /Q "%anri_dir%anridesktoploc.bat" "%appdata%"
REG QUERY "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /V "Desktop" | "%anri_dir%sed" -n s/.\+REG_SZ.\+\\\(.\+\)[^\\]*/\1/gp >> "%appdata%\anridesktoploc.bat"
CALL "%appdata%\anridesktoploc.bat"
SET DESKTOP=%HOMEPATH%\%DESKTOP%
DEL "%appdata%\anridesktoploc.bat"
CD "%DESKTOP%"

set statid1=
set statid2=
set statid3=
set /P statid1=Station ID Line 1 (normally runner name): 
set /P statid2=Station ID Line 2 (normally game name, run type and time): 
set /P statid3=Station ID Line 3 (normally game name, run type and time continued if necessary): 

echo global pal=false > statid_preview.avs
echo import("%anri_dir%nate.avs") >> statid_preview.avs
echo run=blankclip(fps=29.97).audiodub(wavsource("%anri_dir%silence_stereo_48000.wav")) >> statid_preview.avs
echo nate_statid_d1(run,"""%statid1%""","""%statid2%""","""%statid3%""").Lanczos4Resize(640,480).converttoyv12 >> "statid_preview.avs"

"%anri_dir%xvid_encraw.exe" -i "statid_preview.avs" -bitrate 512 -pass1 "statid_preview.stats"
"%anri_dir%xvid_encraw.exe" -i "statid_preview.avs" -bitrate 512 -pass2 "statid_preview.stats" -avi "statid_preview.avi"
del statid_preview.stats
del statid_preview.avs

set statid1=
set statid2=
set statid3=

echo Finished! You will find statid_preview.avi on your Desktop. You can view this video in any player that supports DivX/Xvid.
pause
@echo on